/* Simple LCD Character Display - see http://www.technoblogy.com/show?2BET

   David Johnson-Davies - www.technoblogy.com - 15th September 2018
   ATmega328 @ 8MHz (internal oscillator; BOD disabled)
   
   CC BY 4.0
   Licensed under a Creative Commons Attribution 4.0 International license: 
   http://creativecommons.org/licenses/by/4.0/
*/

// Pin definitions - these are all pin numbers in PORTD (and Arduino pin numbers)
const int data = 1;    // PD1 to PD4 connect to D4 to D7 on the display
const int enable = 5;  // PD5
const int rs = 0;      // PD0

class LCD : public Print {
  public:
    void init();
    void cmd(uint8_t);
    size_t write(uint8_t);
  private:
    void nib(uint8_t);
};

void LCD::init () {
  DDRD = DDRD | 0xF<<data | 1<<enable | 1<<rs;   // Make data E and RS pins outputs
  PORTD = PORTD & ~(1<<rs);                      // Take RS low
  cmd(0x33);                                     // Ensures display is in 8-bit mode
  cmd(0x32);                                     // Puts display in 4-bit mode
  cmd(0x0e);                                     // Display and cursor on
  cmd(0x01);                                     // Clear display
}

// Send four bit nibble to display
void LCD::nib (uint8_t n) {
  PORTD = (PORTD & ~(0xF<<data)) | n<<data | 1<<enable; // Send data and enable high
  PORTD = PORTD & ~(1<<enable);                  // Take enable low
  delay(1);                                      // Allow data to execute on display
}

size_t LCD::write (uint8_t b) {
  nib(b>>4); nib(b&0xf);
  return 1;
}

// Send command
void LCD::cmd (uint8_t c) {
  PORTD = PORTD & ~(1<<rs);                      // Take RS low
  write(c);
  PORTD = PORTD | 1<<rs;                         // Take RS high
  delay(1);                                      // Allow to execute on display
}

// Demo **********************************************

LCD lcd;

void setup() {
  lcd.init();
  lcd.print("Hello");
  lcd.cmd(0xc0);                                 // Cursor to start of second line
  lcd.print("World!");
}

void loop() {
}