/* I2C Display Module
   ATtinyx41, B.O.D. Disabled, ATtiny841, 1 MHz (internal)

   David Johnson-Davies - www.technoblogy.com - 5th August 2016
   
   CC BY 4.0
   Licensed under a Creative Commons Attribution 4.0 International license: 
   http://creativecommons.org/licenses/by/4.0/
*/

// Seven-segment definitions
char charArray[] = {
//  ABCDEFG  Segments
  0b1111110, // 0
  0b0110000, // 1
  0b1101101, // 2
  0b1111001, // 3
  0b0110011, // 4
  0b1011011, // 5
  0b1011111, // 6
  0b1110000, // 7
  0b1111111, // 8
  0b1111011, // 9
  0b1110111, // 10  "A"
  0b0011111, // 11  "B"
  0b1001110, // 12  "C"
  0b0111101, // 13  "D"
  0b1001111, // 14  "E"
  0b1000111, // 15  "F"
  0b0000000, // 16  Space
  0b0000001  // 17  '-'
};

const int I2CAddress = 0x3A;

const int Blank = 16;
const int Dash = 17;

volatile int Buffer[] = {Dash, Dash};
volatile int Write = 0;
volatile int Read = 0;
int Digit = 0;

// Pin assignments

int Digits[] = {PORTA5, PORTA7};

// Display multiplexer **********************************************

void DisplayNextDigit() {
  Digit = Digit ^ 1;                     // Toggle between 0 and 1
  int segs = charArray[Buffer[Digit]];
  DDRA = 0; DDRB = 0;                    // All inputs
  // Set display segments
  PORTA = 0; PORTB = 0;
  DDRB = segs & 0x07;                    // Outputs
  DDRA = (segs>>3) & 0x0F;
  DDRA = DDRA | 1<<Digits[Digit];        // Make it an output
  PORTA = PORTA | 1<<Digits[Digit];      // Make it high
}

// Timer/Counter0 interrupt - multiplexes display
ISR(TIMER1_COMPA_vect) {
  DisplayNextDigit();
}

// I2C Interface **********************************************

// TWI interrupt
ISR(TWI_SLAVE_vect) {
  if (TWSSRA & 1<<TWASIF) {              // Address received
    if (TWSSRA & 1<<TWDIR) {             // Master read
      Read = 0;
      TWSCRB = 3<<TWCMD0;                // ACK
    } else {                             // Master write
      Write = 0;                         // Reset pointer
      TWSCRB = 3<<TWCMD0;                // ACK
    }
  } else if (TWSSRA & 1<<TWDIF) {        // Data interrupt
    if (TWSSRA & 1<<TWDIR) {             // Master read
      if (Read < 2) {
        TWSD = Buffer[Read++];
        TWSCRB = 3<<TWCMD0;
      } else TWSCRB = 2<<TWCMD0;         // Complete transaction
    } else {                             // Master write
      if (Write < 2) Buffer[Write++] = TWSD;
      if (Write < 2) TWSCRB = 3<<TWCMD0; // ACK
      else TWSCRB = 1<<TWAA | 2<<TWCMD0; // NACK and complete
    }
  }
}

// Setup **********************************************

void setup() {
  // Set up Timer/Counter1 to multiplex the display
  TCCR1A = 0<<WGM10;                     // CTC mode; count up to OCR0A
  TCCR1B = 1<<WGM12 | 2<<CS10;           // Divide by 8
  OCR1A = 249;                           // Compare match at 500Hz
  TIMSK1 = TIMSK1 | 1<<OCIE1A;           // Enable compare match interrupt
  // Set up I2C slave
  TWSCRA = 1<<TWDIE | 1<<TWASIE | 1<<TWEN;
  TWSA = I2CAddress<<1;
}

void loop() {
}