/* Flashing Thermometer

   David Johnson-Davies - www.technoblogy.com - 30th January 2016
   ATtiny85 @ 1 MHz (internal oscillator; BOD disabled)
   
   CC BY 4.0
   Licensed under a Creative Commons Attribution 4.0 International license: 
   http://creativecommons.org/licenses/by/4.0/
*/

#include <avr/sleep.h>                                                                                                                                                                                                                                                                                                                                                                             

const int red = 0;                         // PB0
const int green = 2;                       // PB2

// Read temperature **********************************************

int ReadADC() {
  ADCSRA = ADCSRA | 1<<ADEN;               // Enable ADC
  set_sleep_mode(SLEEP_MODE_ADC);
  sleep_enable();
  sleep_cpu();                             // Go into ADC noise reduction mode
  int low, high;                           // Return here on ADC interrupt
  low = ADCL;
  high = ADCH;
  ADCSRA = ADCSRA & ~(1<<ADEN);            // Disable ADC to save power
  return (high<<8 | low);
}
 
ISR(ADC_vect) {
// ADC conversion complete
}

// Flash result on LEDs **********************************************

// Convert value to negabinary
unsigned int NegaBinary (unsigned int value) {
  return (value + 0xAAAAAAAA) ^ 0xAAAAAAAA;
}

// Flash 10-bit integer value, skipping leading zeros
void Flash (unsigned int value) {
  int i=9, colour;
  boolean b, show=false;
  do {
    b = value>>i & 1;
    if (show || b || (i==0)) {
      if (value>>i & 1) colour = red; else colour = green;
      digitalWrite(colour, HIGH);
      WDDelay(0);                              // 12msec flash
      digitalWrite(colour, LOW);
      WDDelay(6);                              // 1 second gap
      show = true;
    }
    i--;
  } while (i>=0);
}

// Watchdog timer **********************************************

// Use Watchdog for time delay; n=0 is 16ms; n=6 is 1sec ; n=9 is 8secs, 
void WDDelay(int n) {
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
  WDTCR = 1<<WDIE | (n & 0x8)<<2 | 1<<WDE | (n & 0x7);
  sleep_enable();
  sleep_cpu();
}

ISR(WDT_vect) {
  // Special sequence to disable watchdog timer
  WDTCR = 1<<WDCE | 1<<WDE;
  WDTCR = 0;
}

// Setup and main loop **********************************************

void setup() {
  // Turn off Timer/Counter0, Timer/Counter1, and USI to save power
  PRR = 1<<PRTIM1 | 1<<PRTIM0 | 1<<PRUSI;
  // Define inputs and outputs
  pinMode(red, OUTPUT);
  pinMode(green, OUTPUT);
  digitalWrite(red, LOW);
  digitalWrite(green, LOW);
  // Set up ADC for temperature
  ADMUX = 0<<REFS2 | 2<<REFS0 | 15<<MUX0;  // temperature and 1.1V reference
  ADCSRA = 1<<ADEN | 1<<ADIE | 3<<ADPS0;   // enable ADC, interrupt, 125kHz ADC clock
}

void loop() {
  int Temperature;
  // Go to sleep to save power until the watchdog timer wakes us up
  WDDelay(9);                              // 8 second delay
  WDDelay(9);                              // and another 8 second delay
  Temperature = (ReadADC()*31 - 8837)/33;  // In degrees Celsius
  Flash(NegaBinary(Temperature));
}